build(vcpkg): add a patched libpng for universal binary support

If I had a nickel for every time we've had to overlay a port for universal binary support, I'd have two nickels. Which isn't a lot, but it's weird that it happened twice Signed-off-by: Seth Flynn <getchoo@tuta.io>
2025-08-03 11:27:33 -04:00 · 2025-07-31 21:37:05 -04:00 · 2025-07-31 21:37:05 -04:00 · f27b6007d6
commit f27b6007d6
parent 5b1debab60
8 changed files with 3327 additions and 0 deletions
--- a/cmake/vcpkg-ports/libpng/README.md
+++ b/cmake/vcpkg-ports/libpng/README.md
@ -0,0 +1,3 @@
+The only difference between this and the upstream vcpkg port is the addition of `target-specific-code.patch`. It's very annoying we need to bundle this entire tree to do that.
+
+-@getchoo
--- a/cmake/vcpkg-ports/libpng/cmake.patch
+++ b/cmake/vcpkg-ports/libpng/cmake.patch
@ -0,0 +1,92 @@
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 1cf5b86e4..e79f8819c 100644
+--- a/CMakeLists.txt
+++ b/CMakeLists.txt
+@@ -143,6 +143,12 @@ find_package(ZLIB REQUIRED)
+ if(UNIX
+    AND NOT (APPLE OR BEOS OR HAIKU)
+    AND NOT EMSCRIPTEN)
+  block(SCOPE_FOR VARIABLES)
+    if(VCPKG_CRT_LINKAGE STREQUAL "static")
+      list(PREPEND CMAKE_FIND_LIBRARY_SUFFIXES "${CMAKE_STATIC_LIBRARY_SUFFIX}")
+    endif()
+    find_library(M_LIBRARY m PATHS ${CMAKE_C_IMPLICIT_LINK_DIRECTORIES})
+  endblock()
+   find_library(M_LIBRARY m)
+   if(M_LIBRARY)
+     set(M_LIBRARY m)
+@@ -236,9 +242,9 @@ if(PNG_HARDWARE_OPTIMIZATIONS)
+ 
+   # Set definitions and sources for MIPS.
+   if(PNG_TARGET_ARCHITECTURE MATCHES "^(mipsel|mips64el)")
+-    set(PNG_MIPS_MSA_POSSIBLE_VALUES on off)
+    set(PNG_MIPS_MSA_POSSIBLE_VALUES on off check)
+     set(PNG_MIPS_MSA
+-        "on"
+        "check"
+         CACHE STRING "Enable MIPS_MSA optimizations: on|off; on is default")
+     set_property(CACHE PNG_MIPS_MSA
+                  PROPERTY STRINGS ${PNG_MIPS_MSA_POSSIBLE_VALUES})
+@@ -271,6 +277,12 @@ if(PNG_HARDWARE_OPTIMIZATIONS)
+           mips/filter_msa_intrinsics.c)
+       add_definitions(-DPNG_MIPS_MSA_OPT=2)
+       add_definitions(-DPNG_MIPS_MMI_OPT=0)
+    elseif(PNG_MIPS_MSA STREQUAL "check")
+      set(libpng_mips_sources
+          mips/mips_init.c
+          mips/filter_msa_intrinsics.c)
+      add_definitions(-DPNG_MIPS_MSA_CHECK_SUPPORTED)
+      add_definitions(-DPNG_MIPS_MMI_CHECK_SUPPORTED)
+     elseif(PNG_MIPS_MMI STREQUAL "on")
+       set(libpng_mips_sources
+           mips/mips_init.c
+@@ -665,7 +677,7 @@ else()
+   # We also need to use a custom suffix, in order to distinguish between the
+   # shared import library name and the static library name.
+   set(PNG_SHARED_OUTPUT_NAME "libpng${PNGLIB_ABI_VERSION}")
+-  set(PNG_STATIC_OUTPUT_NAME "libpng${PNGLIB_ABI_VERSION}_static")
+  set(PNG_STATIC_OUTPUT_NAME "libpng${PNGLIB_ABI_VERSION}")
+ endif()
+ 
+ if(PNG_SHARED)
+@@ -943,10 +955,10 @@ if(PNG_TESTS AND PNG_SHARED)
+                FILES ${PNGSUITE_PNGS})
+ endif()
+ 
+-if(PNG_SHARED AND PNG_TOOLS)
+if(PNG_TOOLS)
+   add_executable(pngfix ${pngfix_sources})
+   target_link_libraries(pngfix
+-                        PRIVATE png_shared)
+                        PRIVATE $<TARGET_NAME_IF_EXISTS:png_shared> $<TARGET_NAME_IF_EXISTS:png_static>) # in vcpkg there's only one
+   set(PNG_BIN_TARGETS pngfix)
+ 
+   add_executable(png-fix-itxt ${png_fix_itxt_sources})
+@@ -1030,12 +1042,15 @@ endif()
+ # We use the same files like ./configure, so we have to set its vars.
+ # Only do this on Windows for Cygwin - the files don't make much sense
+ # outside of a UNIX look-alike.
+-if(NOT WIN32 OR CYGWIN OR MINGW)
+if(1)
+   set(prefix ${CMAKE_INSTALL_PREFIX})
+   set(exec_prefix ${CMAKE_INSTALL_PREFIX})
+   set(libdir ${CMAKE_INSTALL_FULL_LIBDIR})
+   set(includedir ${CMAKE_INSTALL_FULL_INCLUDEDIR})
+-  set(LIBS "-lz -lm")
+  set(LIBS "")
+  if(M_LIBRARY)
+    string(APPEND LIBS "-lm")
+  endif()
+   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libpng.pc.in
+                  ${CMAKE_CURRENT_BINARY_DIR}/libpng${PNGLIB_ABI_VERSION}.pc
+                  @ONLY)
+@@ -1094,6 +1109,9 @@ if(NOT SKIP_INSTALL_PROGRAMS AND NOT SKIP_INSTALL_ALL)
+ endif()
+ 
+ if(NOT SKIP_INSTALL_FILES AND NOT SKIP_INSTALL_ALL)
+  install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libpng${PNGLIB_ABI_VERSION}.pc
+          DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
+elseif(0)
+   # Install the man pages.
+   install(FILES libpng.3 libpngpf.3
+           DESTINATION ${CMAKE_INSTALL_MANDIR}/man3)
--- a/cmake/vcpkg-ports/libpng/libpng-config.cmake
+++ b/cmake/vcpkg-ports/libpng/libpng-config.cmake
@ -0,0 +1,12 @@
+file(READ "${CMAKE_CURRENT_LIST_DIR}/usage" usage)
+message(WARNING "find_package(libpng) is deprecated.\n${usage}")
+
+include(CMakeFindDependencyMacro)
+find_dependency(PNG CONFIG)
+
+if(NOT TARGET png_shared)
+    add_library(png_shared ALIAS PNG::PNG)
+endif()
+if(NOT TARGET png_static)
+    add_library(png_static ALIAS PNG::PNG)
+endif()
--- a/cmake/vcpkg-ports/libpng/portfile.cmake
+++ b/cmake/vcpkg-ports/libpng/portfile.cmake
@ -0,0 +1,122 @@
+# Download the apng patch
+set(LIBPNG_APNG_PATCH_PATH "")
+if ("apng" IN_LIST FEATURES)
+    if(VCPKG_HOST_IS_WINDOWS)
+        # Get (g)awk and gzip installed
+        vcpkg_acquire_msys(MSYS_ROOT PACKAGES gawk gzip)
+        set(AWK_EXE_PATH "${MSYS_ROOT}/usr/bin")
+        vcpkg_add_to_path("${AWK_EXE_PATH}")
+    endif()
+
+    set(LIBPNG_APNG_PATCH_NAME "libpng-${VERSION}-apng.patch")
+    vcpkg_download_distfile(LIBPNG_APNG_PATCH_ARCHIVE
+        URLS "https://downloads.sourceforge.net/project/libpng-apng/libpng16/${VERSION}/${LIBPNG_APNG_PATCH_NAME}.gz"
+        FILENAME "${LIBPNG_APNG_PATCH_NAME}.gz"
+        SHA512 957810c235647bceaacc9754dcb25fdd36177f0f8255ed3eef862d681a53e80e2fc461f8dc083da4a07728b14cf9d2941286c1d745acc9fb131ef767630532f3
+    )
+    set(LIBPNG_APNG_PATCH_PATH "${CURRENT_BUILDTREES_DIR}/src/${LIBPNG_APNG_PATCH_NAME}")
+    if (NOT EXISTS "${LIBPNG_APNG_PATCH_PATH}")
+        file(INSTALL "${LIBPNG_APNG_PATCH_ARCHIVE}" DESTINATION "${CURRENT_BUILDTREES_DIR}/src")
+        vcpkg_execute_required_process(
+            COMMAND gzip -d "${LIBPNG_APNG_PATCH_NAME}.gz"
+            WORKING_DIRECTORY "${CURRENT_BUILDTREES_DIR}/src"
+            ALLOW_IN_DOWNLOAD_MODE
+            LOGNAME extract-patch.log
+        )
+    endif()
+endif()
+
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO pnggroup/libpng
+    REF v${VERSION}
+    SHA512 3a0006256abc6f23f5be1d67b201303ceaaa58ffa901f4659ad95f025b08f5e1c30d374cc251196a2ff1ee3ef4b37bd4d61c7779eabd86922d3bdd047264d9c1
+    HEAD_REF master
+    PATCHES
+        "${LIBPNG_APNG_PATCH_PATH}"
+        cmake.patch
+        target-specific-code.patch
+)
+
+string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "dynamic" PNG_SHARED)
+string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "static" PNG_STATIC)
+
+vcpkg_check_features(
+    OUT_FEATURE_OPTIONS FEATURE_OPTIONS
+    FEATURES
+        tools PNG_TOOLS
+    INVERTED_FEATURES
+        tools SKIP_INSTALL_PROGRAMS
+)
+
+vcpkg_list(SET LIBPNG_HARDWARE_OPTIMIZATIONS_OPTION)
+if(VCPKG_TARGET_IS_IOS)
+    vcpkg_list(APPEND LIBPNG_HARDWARE_OPTIMIZATIONS_OPTION "-DPNG_HARDWARE_OPTIMIZATIONS=OFF")
+endif()
+
+vcpkg_list(SET LD_VERSION_SCRIPT_OPTION)
+if(VCPKG_TARGET_IS_ANDROID)
+    vcpkg_list(APPEND LD_VERSION_SCRIPT_OPTION "-Dld-version-script=OFF")
+    if(VCPKG_TARGET_ARCHITECTURE STREQUAL "arm")
+        vcpkg_cmake_get_vars(cmake_vars_file)
+        include("${cmake_vars_file}")
+        if(VCPKG_DETECTED_CMAKE_ANDROID_ARM_NEON)
+            vcpkg_list(APPEND LIBPNG_HARDWARE_OPTIMIZATIONS_OPTION "-DPNG_ARM_NEON=on")
+        else()
+            # for armeabi-v7a, check whether NEON is available
+            vcpkg_list(APPEND LIBPNG_HARDWARE_OPTIMIZATIONS_OPTION "-DPNG_ARM_NEON=check")
+        endif()
+    endif()
+endif()
+
+if(VCPKG_TARGET_ARCHITECTURE STREQUAL "arm64" AND VCPKG_TARGET_IS_LINUX)
+  vcpkg_list(APPEND LIBPNG_HARDWARE_OPTIMIZATIONS_OPTION "-DPNG_ARM_NEON=on")
+endif()
+
+vcpkg_cmake_configure(
+    SOURCE_PATH "${SOURCE_PATH}"
+    OPTIONS
+        ${LIBPNG_HARDWARE_OPTIMIZATIONS_OPTION}
+        ${LD_VERSION_SCRIPT_OPTION}
+        -DPNG_STATIC=${PNG_STATIC}
+        -DPNG_SHARED=${PNG_SHARED}
+        -DPNG_FRAMEWORK=OFF
+        -DPNG_TESTS=OFF
+        -DSKIP_INSTALL_EXECUTABLES=ON
+        -DSKIP_INSTALL_FILES=OFF
+        ${FEATURE_OPTIONS}
+    OPTIONS_DEBUG
+        -DSKIP_INSTALL_HEADERS=ON
+    MAYBE_UNUSED_VARIABLES
+        PNG_ARM_NEON
+)
+vcpkg_cmake_install()
+vcpkg_cmake_config_fixup(PACKAGE_NAME png CONFIG_PATH lib/cmake/PNG)
+vcpkg_cmake_config_fixup(CONFIG_PATH lib/libpng)
+file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/vcpkg-cmake-wrapper.cmake" DESTINATION "${CURRENT_PACKAGES_DIR}/share/png")
+
+# unofficial legacy usage
+file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/libpng-config.cmake" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
+
+vcpkg_fixup_pkgconfig()
+if(VCPKG_TARGET_IS_WINDOWS AND NOT VCPKG_TARGET_IS_MINGW)
+    if(NOT VCPKG_BUILD_TYPE)
+        vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/debug/lib/pkgconfig/libpng16.pc" "-lpng16" "-llibpng16d")
+        file(INSTALL "${CURRENT_PACKAGES_DIR}/debug/lib/pkgconfig/libpng16.pc" DESTINATION "${CURRENT_PACKAGES_DIR}/debug/lib/pkgconfig" RENAME "libpng.pc")
+    endif()
+    vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/lib/pkgconfig/libpng16.pc" "-lpng16" "-llibpng16")
+elseif(NOT VCPKG_BUILD_TYPE)
+    vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/debug/lib/pkgconfig/libpng16.pc" "-lpng16" "-lpng16d")
+    file(INSTALL "${CURRENT_PACKAGES_DIR}/debug/lib/pkgconfig/libpng16.pc" DESTINATION "${CURRENT_PACKAGES_DIR}/debug/lib/pkgconfig" RENAME "libpng.pc")
+endif()
+file(INSTALL "${CURRENT_PACKAGES_DIR}/lib/pkgconfig/libpng16.pc" DESTINATION "${CURRENT_PACKAGES_DIR}/lib/pkgconfig" RENAME "libpng.pc")
+
+vcpkg_copy_pdbs()
+
+if(PNG_TOOLS)
+    vcpkg_copy_tools(TOOL_NAMES "pngfix" "png-fix-itxt" AUTO_CLEAN)
+endif()
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share")
+file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/usage" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/LICENSE")
--- a/cmake/vcpkg-ports/libpng/target-specific-code.patch
+++ b/cmake/vcpkg-ports/libpng/target-specific-code.patch
--- a/cmake/vcpkg-ports/libpng/usage
+++ b/cmake/vcpkg-ports/libpng/usage
@ -0,0 +1,4 @@
+libpng provides CMake targets:
+
+  find_package(PNG REQUIRED)
+  target_link_libraries(main PRIVATE PNG::PNG)
--- a/cmake/vcpkg-ports/libpng/vcpkg-cmake-wrapper.cmake
+++ b/cmake/vcpkg-ports/libpng/vcpkg-cmake-wrapper.cmake
@ -0,0 +1,3 @@
+find_library(PNG_LIBRARY_RELEASE NAMES png16 libpng16 NAMES_PER_DIR PATHS "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/lib" NO_DEFAULT_PATH)
+find_library(PNG_LIBRARY_DEBUG NAMES png16d libpng16d NAMES_PER_DIR PATHS "${_VCPKG_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/debug/lib" NO_DEFAULT_PATH)
+_find_package(${ARGS})
--- a/cmake/vcpkg-ports/libpng/vcpkg.json
+++ b/cmake/vcpkg-ports/libpng/vcpkg.json
@ -0,0 +1,32 @@
+{
+  "name": "libpng",
+  "version": "1.6.48",
+  "description": "libpng is a library implementing an interface for reading and writing PNG (Portable Network Graphics) format files",
+  "homepage": "https://github.com/pnggroup/libpng",
+  "license": "libpng-2.0",
+  "dependencies": [
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-config",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-get-vars",
+      "host": true,
+      "platform": "arm & android"
+    },
+    "zlib"
+  ],
+  "features": {
+    "apng": {
+      "description": "This is backward compatible with the regular libpng, both in library usage and format"
+    },
+    "tools": {
+      "description": "Build the libpng tools",
+      "supports": "!android & !ios"
+    }
+  }
+}