0a6a1f1d05
This brings our tree to NetBSD 7.0, as found on -current on the 10-10-2015. This updates: - LLVM to 3.6.1 - GCC to GCC 5.1 - Replace minix/commands/zdump with usr.bin/zdump - external/bsd/libelf has moved to /external/bsd/elftoolchain/ - Import ctwm - Drop sprintf from libminc Change-Id: I149836ac18e9326be9353958bab9b266efb056f0
49 lines
883 B
ArmAsm
49 lines
883 B
ArmAsm
/*
|
|
* Written by J.T. Conklin <jtc@NetBSD.org>.
|
|
* Public domain.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
|
|
#if defined(LIBC_SCCS)
|
|
RCSID("$NetBSD: memcmp.S,v 1.3 2014/03/22 19:38:46 jakllsch Exp $")
|
|
#endif
|
|
|
|
ENTRY(memcmp)
|
|
pushl %edi
|
|
pushl %esi
|
|
movl 12(%esp),%edi
|
|
movl 16(%esp),%esi
|
|
|
|
movl 20(%esp),%ecx /* compare by words */
|
|
shrl $2,%ecx
|
|
repe
|
|
cmpsl
|
|
jne L5 /* do we match so far? */
|
|
|
|
movl 20(%esp),%ecx /* compare remainder by bytes */
|
|
andl $3,%ecx
|
|
repe
|
|
cmpsb
|
|
jne L6 /* do we match? */
|
|
|
|
xorl %eax,%eax /* we match, return zero */
|
|
popl %esi
|
|
popl %edi
|
|
ret
|
|
|
|
L5: movl $4,%ecx /* We know that one of the next */
|
|
subl %ecx,%edi /* four pairs of bytes do not */
|
|
subl %ecx,%esi /* match. */
|
|
repe
|
|
cmpsb
|
|
L6: xorl %eax,%eax /* Perform unsigned comparison */
|
|
movb -1(%edi),%al
|
|
xorl %edx,%edx
|
|
movb -1(%esi),%dl
|
|
subl %edx,%eax
|
|
popl %esi
|
|
popl %edi
|
|
ret
|
|
END(memcmp)
|