84d9c625bf
- Fix for possible unset uid/gid in toproto
- Fix for default mtree style
- Update libelf
- Importing libexecinfo
- Resynchronize GCC, mpc, gmp, mpfr
- build.sh: Replace params with show-params.
This has been done as the make target has been renamed in the same
way, while a new target named params has been added. This new
target generates a file containing all the parameters, instead of
printing it on the console.
- Update test48 with new etc/services (Fix by Ben Gras <ben@minix3.org)
get getservbyport() out of the inner loop
Change-Id: Ie6ad5226fa2621ff9f0dee8782ea48f9443d2091
101 lines
3.7 KiB
ArmAsm
101 lines
3.7 KiB
ArmAsm
/* $NetBSD: atomic_add_8.S,v 1.1 2013/11/08 22:42:52 matt Exp $ */
|
|
|
|
/*-
|
|
* Copyright (c) 2013 The NetBSD Foundation, Inc.
|
|
* All rights reserved.
|
|
*
|
|
* This code is derived from software contributed to The NetBSD Foundation
|
|
* by Matt Thomas <matt@3am-software.com>
|
|
*
|
|
* Redistribution and use in source and binary forms, with or without
|
|
* modification, are permitted provided that the following conditions
|
|
* are met:
|
|
* 1. Redistributions of source code must retain the above copyright
|
|
* notice, this list of conditions and the following disclaimer.
|
|
* 2. Redistributions in binary form must reproduce the above copyright
|
|
* notice, this list of conditions and the following disclaimer in the
|
|
* documentation and/or other materials provided with the distribution.
|
|
*
|
|
* THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
|
|
* ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
|
|
* TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
|
|
* PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
|
|
* BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
|
|
* CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
|
|
* SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
|
|
* INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
|
|
* CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
|
|
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
|
|
* POSSIBILITY OF SUCH DAMAGE.
|
|
*/
|
|
|
|
#include "atomic_op_asm.h"
|
|
|
|
#ifdef _ARM_ARCH_6
|
|
|
|
ENTRY_NP(_atomic_sub_8)
|
|
negs r1, r1
|
|
/* FALLTHROUGH */
|
|
ENTRY_NP(_atomic_add_8)
|
|
mov ip, r0
|
|
1: ldrexb r0, [ip] /* load old value */
|
|
adds r3, r0, r1 /* calculate new value */
|
|
strexb r2, r3, [ip] /* try to store */
|
|
cmp r2, #0 /* succeed? */
|
|
bne 1b /* no, try again */
|
|
#ifdef _ARM_ARCH_7
|
|
dmb
|
|
#else
|
|
mcr p15, 0, r2, c7, c10, 5 /* data memory barrier */
|
|
#endif
|
|
RET /* return old value */
|
|
END(_atomic_add_8)
|
|
END(_atomic_sub_8)
|
|
|
|
ATOMIC_OP_ALIAS(atomic_add_8,_atomic_add_8)
|
|
ATOMIC_OP_ALIAS(atomic_add_char,_atomic_add_8)
|
|
ATOMIC_OP_ALIAS(atomic_add_uchar,_atomic_add_8)
|
|
STRONG_ALIAS(__sync_fetch_and_add_1,_atomic_add_8)
|
|
STRONG_ALIAS(_atomic_add_char,_atomic_add_8)
|
|
STRONG_ALIAS(_atomic_add_uchar,_atomic_add_8)
|
|
|
|
ATOMIC_OP_ALIAS(atomic_sub_8,_atomic_sub_8)
|
|
ATOMIC_OP_ALIAS(atomic_sub_char,_atomic_sub_8)
|
|
ATOMIC_OP_ALIAS(atomic_sub_uchar,_atomic_sub_8)
|
|
STRONG_ALIAS(__sync_fetch_and_sub_1,_atomic_sub_8)
|
|
STRONG_ALIAS(_atomic_sub_char,_atomic_sub_8)
|
|
STRONG_ALIAS(_atomic_sub_uchar,_atomic_sub_8)
|
|
|
|
ENTRY_NP(_atomic_sub_8_nv)
|
|
negs r1, r1
|
|
/* FALLTHROUGH */
|
|
ENTRY_NP(_atomic_add_8_nv)
|
|
mov ip, r0 /* need r0 for return value */
|
|
1: ldrexb r0, [ip] /* load old value */
|
|
adds r0, r0, r1 /* calculate new value (return value) */
|
|
strexb r2, r0, [ip] /* try to store */
|
|
cmp r2, #0 /* succeed? */
|
|
bne 1b /* no, try again? */
|
|
#ifdef _ARM_ARCH_7
|
|
dmb
|
|
#else
|
|
mcr p15, 0, r2, c7, c10, 5 /* data memory barrier */
|
|
#endif
|
|
RET /* return new value */
|
|
END(_atomic_add_8_nv)
|
|
END(_atomic_sub_8_nv)
|
|
ATOMIC_OP_ALIAS(atomic_add_8_nv,_atomic_add_8_nv)
|
|
ATOMIC_OP_ALIAS(atomic_add_char_nv,_atomic_add_8_nv)
|
|
ATOMIC_OP_ALIAS(atomic_add_uchar_nv,_atomic_add_8_nv)
|
|
STRONG_ALIAS(__sync_add_and_fetch_1,_atomic_add_8_nv)
|
|
STRONG_ALIAS(_atomic_add_char_nv,_atomic_add_8_nv)
|
|
STRONG_ALIAS(_atomic_add_uchar_nv,_atomic_add_8_nv)
|
|
|
|
ATOMIC_OP_ALIAS(atomic_sub_8_nv,_atomic_sub_8_nv)
|
|
ATOMIC_OP_ALIAS(atomic_sub_char_nv,_atomic_sub_8_nv)
|
|
ATOMIC_OP_ALIAS(atomic_sub_uchar_nv,_atomic_sub_8_nv)
|
|
STRONG_ALIAS(__sync_sub_and_fetch_1,_atomic_sub_8_nv)
|
|
STRONG_ALIAS(_atomic_sub_char_nv,_atomic_sub_8_nv)
|
|
STRONG_ALIAS(_atomic_sub_uchar_nv,_atomic_sub_8_nv)
|
|
#endif /* _ARM_ARCH_6 */
|