2fe8fb192f
There is important information about booting non-ack images in docs/UPDATING. ack/aout-format images can't be built any more, and booting clang/ELF-format ones is a little different. Updating to the new boot monitor is recommended. Changes in this commit: . drop boot monitor -> allowing dropping ack support . facility to copy ELF boot files to /boot so that old boot monitor can still boot fairly easily, see UPDATING . no more ack-format libraries -> single-case libraries . some cleanup of OBJECT_FMT, COMPILER_TYPE, etc cases . drop several ack toolchain commands, but not all support commands (e.g. aal is gone but acksize is not yet). . a few libc files moved to netbsd libc dir . new /bin/date as minix date used code in libc/ . test compile fix . harmonize includes . /usr/lib is no longer special: without ack, /usr/lib plays no kind of special bootstrapping role any more and bootstrapping is done exclusively through packages, so releases depend even less on the state of the machine making them now. . rename nbsd_lib* to lib* . reduce mtree
56 lines
1022 B
ArmAsm
56 lines
1022 B
ArmAsm
/*
|
|
* Written by J.T. Conklin <jtc@NetBSD.org>.
|
|
* Public domain.
|
|
*/
|
|
|
|
#include <machine/asm.h>
|
|
|
|
#include "abi.h"
|
|
|
|
|
|
RCSID("$NetBSD: e_expf.S,v 1.6 2008/06/24 17:27:56 drochner Exp $")
|
|
|
|
/* e^x = 2^(x * log2(e)) */
|
|
ENTRY(__ieee754_expf)
|
|
XMM_ONE_ARG_FLOAT_PROLOGUE
|
|
|
|
/*
|
|
* catch +/-Inf and NaN arguments
|
|
*/
|
|
movl ARG_FLOAT_ONE,%eax
|
|
andl $0x7fffffff,%eax
|
|
cmpl $0x7f800000,%eax
|
|
jae x_Inf_or_NaN
|
|
|
|
flds ARG_FLOAT_ONE
|
|
fldl2e
|
|
fmulp /* x * log2(e) */
|
|
fld %st(0)
|
|
frndint /* int(x * log2(e)) */
|
|
fsubr %st(0),%st(1) /* fract(x * log2(e)) */
|
|
fxch
|
|
f2xm1 /* 2^(fract(x * log2(e))) - 1 */
|
|
fld1
|
|
faddp /* 2^(fract(x * log2(e))) */
|
|
fscale /* e^x */
|
|
fstp %st(1)
|
|
XMM_FLOAT_EPILOGUE
|
|
ret
|
|
|
|
x_Inf_or_NaN:
|
|
/*
|
|
* Return 0 if x is -Inf. Otherwise just return x, although the
|
|
* C version would return (x + x) (Real Indefinite) if x is a NaN.
|
|
*/
|
|
movl ARG_FLOAT_ONE,%eax
|
|
cmpl $0xff800000,%eax
|
|
jne x_not_minus_Inf
|
|
fldz
|
|
XMM_FLOAT_EPILOGUE
|
|
ret
|
|
|
|
x_not_minus_Inf:
|
|
flds ARG_FLOAT_ONE
|
|
XMM_FLOAT_EPILOGUE
|
|
ret
|