b6cbf7203b
This patch imports the unmodified current version of NetBSD libc. The NetBSD includes are in /nbsd_include, while the libc code itself is split between lib/nbsd_libc and common/lib/libc.
71 lines
2.9 KiB
ArmAsm
71 lines
2.9 KiB
ArmAsm
/* $NetBSD: atomic_add_32.S,v 1.2 2008/08/16 07:12:39 matt Exp $ */
|
|
|
|
/*-
|
|
* Copyright (c) 2008 The NetBSD Foundation, Inc.
|
|
* All rights reserved.
|
|
*
|
|
* This code is derived from software contributed to The NetBSD Foundation
|
|
* by Matt Thomas <matt@3am-software.com>
|
|
*
|
|
* Redistribution and use in source and binary forms, with or without
|
|
* modification, are permitted provided that the following conditions
|
|
* are met:
|
|
* 1. Redistributions of source code must retain the above copyright
|
|
* notice, this list of conditions and the following disclaimer.
|
|
* 2. Redistributions in binary form must reproduce the above copyright
|
|
* notice, this list of conditions and the following disclaimer in the
|
|
* documentation and/or other materials provided with the distribution.
|
|
*
|
|
* THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
|
|
* ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
|
|
* TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
|
|
* PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
|
|
* BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
|
|
* CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
|
|
* SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
|
|
* INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
|
|
* CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
|
|
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
|
|
* POSSIBILITY OF SUCH DAMAGE.
|
|
*/
|
|
|
|
#include "atomic_op_asm.h"
|
|
|
|
#ifdef _ARM_ARCH_6
|
|
|
|
ENTRY_NP(_atomic_add_32)
|
|
mov r3, r0 /* need r0 for return value */
|
|
1: ldrex r0, [r3] /* load old value (to be returned) */
|
|
add r2, r0, r1 /* calculate new value */
|
|
strex ip, r2, [r3] /* try to store */
|
|
cmp ip, #0 /* succeed? */
|
|
bne 1b /* no, try again */
|
|
RET /* return old value */
|
|
END(_atomic_add_32)
|
|
ATOMIC_OP_ALIAS(atomic_add_32,_atomic_add_32)
|
|
ATOMIC_OP_ALIAS(atomic_add_int,_atomic_add_32)
|
|
ATOMIC_OP_ALIAS(atomic_add_long,_atomic_add_32)
|
|
ATOMIC_OP_ALIAS(atomic_add_ptr,_atomic_add_32)
|
|
STRONG_ALIAS(_atomic_add_int,_atomic_add_32)
|
|
STRONG_ALIAS(_atomic_add_long,_atomic_add_32)
|
|
STRONG_ALIAS(_atomic_add_ptr,_atomic_add_32)
|
|
|
|
ENTRY_NP(_atomic_add_32_nv)
|
|
mov r3, r0 /* need r0 for return value */
|
|
1: ldrex r0, [r3] /* load old value */
|
|
add r0, r0, r1 /* calculate new value (return value) */
|
|
strex r2, r0, [r3] /* try to store */
|
|
cmp r2, #0 /* succeed? */
|
|
bne 1b /* no, try again? */
|
|
RET /* return new value */
|
|
END(_atomic_add_32_nv)
|
|
ATOMIC_OP_ALIAS(atomic_add_32_nv,_atomic_add_32_nv)
|
|
ATOMIC_OP_ALIAS(atomic_add_int_nv,_atomic_add_32_nv)
|
|
ATOMIC_OP_ALIAS(atomic_add_long_nv,_atomic_add_32_nv)
|
|
ATOMIC_OP_ALIAS(atomic_add_ptr_nv,_atomic_add_32_nv)
|
|
STRONG_ALIAS(_atomic_add_int_nv,_atomic_add_32_nv)
|
|
STRONG_ALIAS(_atomic_add_long_nv,_atomic_add_32_nv)
|
|
STRONG_ALIAS(_atomic_add_ptr_nv,_atomic_add_32_nv)
|
|
|
|
#endif /* _ARM_ARCH_6 */
|